Artifact 8c2f46ed3bca5d878e5d66d0b5ad90621e79aaaf:

• File Setup/release_mono.bat — part of check-in [eadbd86b54] at 2016-04-18 20:07:07 on branch trunk — Add support for Mono to the release process. (user: mistachkin size: 1460)

@ECHO OFF

::
:: release_mono.bat --
::
:: Mono Release Tool
::
:: Written by Joe Mistachkin.
:: Released to the public domain, use at your own risk!
::

SETLOCAL

REM SET __ECHO=ECHO
REM SET __ECHO3=ECHO
IF NOT DEFINED _AECHO (SET _AECHO=REM)
IF NOT DEFINED _CECHO (SET _CECHO=REM)
IF NOT DEFINED _VECHO (SET _VECHO=REM)

%_AECHO% Running %0 %*

SET DUMMY2=%1

IF DEFINED DUMMY2 (
  GOTO usage
)

SET TOOLS=%~dp0
SET TOOLS=%TOOLS:~0,-1%

%_VECHO% Tools = '%TOOLS%'

IF DEFINED RELEASE_DEBUG (
  SET RELEASE_CONFIGURATIONS=DebugManagedOnly ReleaseManagedOnly
) ELSE (
  SET RELEASE_CONFIGURATIONS=ReleaseManagedOnly
)

SET BASE_CONFIGURATIONSUFFIX=MonoOnPosix
SET YEARS=2013
SET PLATFORMS=MSIL
SET BASE_PLATFORM=Mono
SET TYPE=binary
SET RELEASE_MANAGEDONLY=1

CALL :fn_ResetErrorLevel

%__ECHO3% CALL "%TOOLS%\release_all.bat"

IF ERRORLEVEL 1 (
  ECHO Failed to build Mono release files.
  GOTO errors
)

GOTO no_errors

:fn_ResetErrorLevel
  VERIFY > NUL
  GOTO :EOF

:fn_SetErrorLevel
  VERIFY MAYBE 2> NUL
  GOTO :EOF

:usage
  ECHO.
  ECHO Usage: %~nx0
  ECHO.
  GOTO errors

:errors
  CALL :fn_SetErrorLevel
  ENDLOCAL
  ECHO.
  ECHO Release failure, errors were encountered.
  GOTO end_of_file

:no_errors
  CALL :fn_ResetErrorLevel
  ENDLOCAL
  ECHO.
  ECHO Release success, no errors were encountered.
  GOTO end_of_file

:end_of_file
%__ECHO% EXIT /B %ERRORLEVEL%